refactor structure

src/autoloads/AudioManager.gd

@@ -0,0 +1,75 @@
+extends Node
+
+const MUSIC_PATH := "res://assets/audio/music/Space Horror InGame Music (Exploration) _Clement Panchout.wav"
+const UI_CLICK_SOUND_PATH := "res://assets/audio/sfx/817587__silverdubloons__tick06.wav"
+
+var music_player: AudioStreamPlayer
+var ui_click_player: AudioStreamPlayer
+var click_stream: AudioStream
+
+func _ready():
+	music_player = AudioStreamPlayer.new()
+	add_child(music_player)
+
+	ui_click_player = AudioStreamPlayer.new()
+	ui_click_player.bus = "SFX"
+	add_child(ui_click_player)
+
+	click_stream = load(UI_CLICK_SOUND_PATH)
+
+	var orig_stream = _load_stream()
+	if not orig_stream:
+		push_error("Failed to load music stream: %s" % MUSIC_PATH)
+		return
+
+	var stream = orig_stream.duplicate(true) as AudioStream
+	_configure_stream_loop(stream)
+	music_player.stream = stream
+	_configure_audio_bus()
+
+	if SettingsManager.get_setting("music_volume") <= 0:
+		return
+
+	_start_music()
+
+func _load_stream() -> AudioStream:
+	var res = load(MUSIC_PATH)
+	if not res or not res is AudioStream:
+		return null
+	return res
+
+func _configure_stream_loop(stream: AudioStream) -> void:
+	if stream is AudioStreamWAV:
+		stream.loop_mode = AudioStreamWAV.LOOP_FORWARD
+	elif stream is AudioStreamOggVorbis:
+		stream.loop = true
+
+func _configure_audio_bus() -> void:
+	music_player.bus = "Music"
+	music_player.volume_db = linear_to_db(SettingsManager.get_setting("music_volume"))
+
+func update_music_volume(volume: float) -> void:
+	var volume_db = linear_to_db(volume)
+	music_player.volume_db = volume_db
+	AudioServer.set_bus_volume_db(AudioServer.get_bus_index("Music"), volume_db)
+
+	if volume > 0:
+		_start_music()
+	else:
+		_stop_music()
+
+func _start_music() -> void:
+	if music_player.playing:
+		return
+	music_player.play()
+
+func _stop_music() -> void:
+	if not music_player.playing:
+		return
+	music_player.stop()
+
+func play_ui_click() -> void:
+	if not click_stream:
+		return
+	ui_click_player.stream = click_stream
+	ui_click_player.play()

src/autoloads/GameManager.gd

@@ -0,0 +1,30 @@
+extends Node
+
+const GAME_SCENE_PATH := "res://scenes/game/game.tscn"
+const MAIN_SCENE_PATH := "res://scenes/main/main.tscn"
+const MATCH3_SCENE_PATH := "res://scenes/match3/match3.tscn"
+
+func start_new_game() -> void:
+	var packed_scene := load(GAME_SCENE_PATH)
+	if not packed_scene or not packed_scene is PackedScene:
+		push_error("Failed to load Game scene at: %s" % GAME_SCENE_PATH)
+		return
+	get_tree().change_scene_to_packed(packed_scene)
+
+func save_game() -> void:
+	print("Game saved (mock)")
+
+func exit_to_main_menu() -> void:
+	var packed_scene := load(MAIN_SCENE_PATH)
+	if not packed_scene or not packed_scene is PackedScene:
+		push_error("Failed to load Main scene at: %s" % MAIN_SCENE_PATH)
+		return
+	get_tree().change_scene_to_packed(packed_scene)
+
+func start_match3_game() -> void:
+	var packed_scene := load(MATCH3_SCENE_PATH)
+	if not packed_scene or not packed_scene is PackedScene:
+		push_error("Failed to load Match3 scene at: %s" % MATCH3_SCENE_PATH)
+		return
+	get_tree().change_scene_to_packed(packed_scene)
+	

src/autoloads/LocalizationManager.gd

@@ -0,0 +1,11 @@
+extends Node
+
+func _ready():
+	# Set default locale if not already set
+	if TranslationServer.get_locale() == "":
+		TranslationServer.set_locale("en")
+
+func change_language(locale: String):
+	TranslationServer.set_locale(locale)
+	# Signal to update UI elements
+	get_tree().call_group("localizable", "update_text")

src/autoloads/SettingsManager.gd

@@ -0,0 +1,90 @@
+extends Node
+
+const LANGUAGES_JSON_PATH := "res://localization/languages.json"
+const SETTINGS_FILE = "user://settings.cfg"
+# dev `user://`=`%APPDATA%\Godot\app_userdata\Skelly`
+# prod `user://`=`%APPDATA%\Skelly\`
+
+var settings = {
+}
+
+var default_settings = {
+	"master_volume": 0.50,
+	"music_volume": 0.40,
+	"sfx_volume": 0.50,
+	"language": "en"
+}
+
+var languages_data = {}
+
+func _ready():
+	print("SettingsManager ready")
+	load_languages()
+	load_settings()
+
+func load_settings():
+	var config = ConfigFile.new()
+	if config.load(SETTINGS_FILE) == OK:
+		for key in default_settings.keys():
+			settings[key] = config.get_value("settings", key, default_settings[key])
+		print("Settings loaded: ", settings)
+	else:
+		print("No settings file found, using defaults")
+	print("Language is set to: ", settings["language"])
+	TranslationServer.set_locale(settings["language"])
+	AudioServer.set_bus_volume_db(AudioServer.get_bus_index("Master"), linear_to_db(settings["master_volume"]))
+	AudioServer.set_bus_volume_db(AudioServer.get_bus_index("Music"), linear_to_db(settings["music_volume"]))
+	AudioServer.set_bus_volume_db(AudioServer.get_bus_index("SFX"), linear_to_db(settings["sfx_volume"]))
+
+
+func save_settings():
+	var config = ConfigFile.new()
+	for key in settings.keys():
+		config.set_value("settings", key, settings[key])
+	config.save(SETTINGS_FILE)
+	print("Settings saved: ", settings)
+
+func get_setting(key: String):
+	return settings.get(key)
+
+func set_setting(key: String, value):
+	settings[key] = value
+	_apply_setting_side_effect(key, value)
+
+func _apply_setting_side_effect(key: String, value) -> void:
+	match key:
+		"language":
+			TranslationServer.set_locale(value)
+		"master_volume":
+			AudioServer.set_bus_volume_db(AudioServer.get_bus_index("Master"), linear_to_db(value))
+		"music_volume":
+			AudioManager.update_music_volume(value)
+		"sfx_volume":
+			AudioServer.set_bus_volume_db(AudioServer.get_bus_index("SFX"), linear_to_db(value))
+
+func load_languages():
+	var file = FileAccess.open(LANGUAGES_JSON_PATH, FileAccess.READ)
+	if not file:
+		print("Could not open languages.json")
+		return
+
+	var json_string = file.get_as_text()
+	file.close()
+
+	var json = JSON.new()
+	if json.parse(json_string) != OK:
+		print("Error parsing languages.json")
+		return
+
+	languages_data = json.data
+	if languages_data.has("languages"):
+		print("Languages loaded: ", languages_data.languages.keys())
+
+func get_languages_data():
+	return languages_data
+
+func reset_settings_to_defaults() -> void:
+	for key in default_settings.keys():
+		settings[key] = default_settings[key]
+		_apply_setting_side_effect(key, settings[key])
+	save_settings()