extends Node

const SETTINGS_FILE = "user://settings.cfg"
# dev `user://`=`%APPDATA%\Godot\app_userdata\Skelly`
# prod `user://`=`%APPDATA%\Skelly\`

var settings = {
}

var default_settings = {
	"master_volume": 0.50,
	"music_volume": 0.40,
	"sfx_volume": 0.50,
	"language": "en"
}

var languages_data = {}

func _ready():
	print("SettingsManager ready")
	load_languages()
	load_settings()

func load_settings():
	var config = ConfigFile.new()
	if config.load(SETTINGS_FILE) == OK:
		for key in default_settings.keys():
			settings[key] = config.get_value("settings", key, default_settings[key])
		print("Settings loaded: ", settings)
	else:
		print("No settings file found, using defaults")
	print("Language is set to: ", settings["language"])
	TranslationServer.set_locale(settings["language"])
	AudioServer.set_bus_volume_db(AudioServer.get_bus_index("Master"), linear_to_db(settings["master_volume"]))
	AudioServer.set_bus_volume_db(AudioServer.get_bus_index("Music"), linear_to_db(settings["music_volume"]))
	AudioServer.set_bus_volume_db(AudioServer.get_bus_index("SFX"), linear_to_db(settings["sfx_volume"]))


func save_settings():
	var config = ConfigFile.new()
	for key in settings.keys():
		config.set_value("settings", key, settings[key])
	config.save(SETTINGS_FILE)
	print("Settings saved: ", settings)

func get_setting(key: String):
	return settings.get(key)

func set_setting(key: String, value):
	settings[key] = value
	save_settings()

func load_languages():
	var file = FileAccess.open("res://localization/languages.json", FileAccess.READ)
	if file:
		var json_string = file.get_as_text()
		file.close()
		var json = JSON.new()
		var parse_result = json.parse(json_string)
		if parse_result == OK:
			languages_data = json.data
			print("Languages loaded: ", languages_data.languages.keys())
		else:
			print("Error parsing languages.json")
	else:
		print("Could not open languages.json")

func get_languages_data():
	return languages_data